;不具合があっても、このスクリプトを公開している水っぽいスープは責任を負いません。
;標準サンプルと、組み込み自由のライセンスのモジュールしか利用していないので
;これを元に何かを作られるのは自由です。バグがあったら勝手に修正してください・・・
;画像はご自身で用意をお願いします。　http://pronama.azurewebsites.net/pronama/download/

#include "mod_rss.as"                   ;RSS取得に必要
#include "module_lwm2.hsp"              ;アルファウィンドウ作成に必要
;モジュールの入手先、http://www.placeark.com/program_hsp_module.html

    url="http://feedproxy.google.com/hitokuchi_4410"    ;東京の天気予報のRSSのアドレス
                                                        ;他を試したい方は、http://www.weathermap.co.jp/hitokuchi_rss/
    
    ;透過用
    buffer 1,400,250                    ;仮想画面を初期化
    picload "sd20_lie-down_a.jpg",0     ;アルファウィンドウ用画像の読み込み
    
    ;メインウィンドウ
    bgscr 0,400,250,2                   ;枠のないウィンドウを初期化
    picload "sd20_lie-down.jpg",0       ;通常の画像の読み込み

    title "プロ生ちゃんのお天気ツール"  ;タイトル変更
    font "MS ゴシック",23,1+16          ;大きさ、アンチエイリアス
    
    gosub *rssSub                       ;RSS取得部分をサブルーチン化

    onclick gosub *OnClickSub           ;クリックしたらサブルーチンへ

    wait 10
    gsel 0,2                            ;最上面に表示
    
    stop

*OnClickSub
    if wparam=1:sendmsg hwnd,$a1,2,0    ;左クリックで移動
    if wparam=2 {                       ;右クリックでRSS更新
    gosub *rssSub
    }
    return                              ;サブルーチンから復帰

*rssSub
    gsel 0
    redraw 0                            ;仮想画面だけ書き換え
    rssload desc, link, url, 5          ;RSS取得

    if stat=1 : dialog "取得に失敗しました。" : end
    if stat=2 : dialog "RSSではありません。" : end
    strrep desc(4)," ","\n"             ;明日の天気の半角スペースを改行に置換
    
    color 255,255,255                   ;描画色を白
    boxf 200,45,300,140                 ;四角を描画

    color 0,0,0                         ;描画色を黒
    pos 200,45                          ;文字の表示位置
    mes desc(4)                         ;明日の天気を表示

    enableAlphaBlendWindow 1            ;ID 1のウィンドウのR値から
                                        ;アルファブレンドウィンドウ作成

    redraw 1                            ;実際の画面に反映

    return                              ;サブルーチンから復帰